<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package overload;

use strict;
no strict 'refs';

our $VERSION = '1.37';

our %ops = (
    with_assign         =&gt; "+ - * / % ** &lt;&lt; &gt;&gt; x .",
    assign              =&gt; "+= -= *= /= %= **= &lt;&lt;= &gt;&gt;= x= .=",
    num_comparison      =&gt; "&lt; &lt;= &gt;  &gt;= == !=",
    '3way_comparison'   =&gt; "&lt;=&gt; cmp",
    str_comparison      =&gt; "lt le gt ge eq ne",
    binary              =&gt; '&amp; &amp;= | |= ^ ^= &amp;. &amp;.= |. |.= ^. ^.=',
    unary               =&gt; "neg ! ~ ~.",
    mutators            =&gt; '++ --',
    func                =&gt; "atan2 cos sin exp abs log sqrt int",
    conversion          =&gt; 'bool "" 0+ qr',
    iterators           =&gt; '&lt;&gt;',
    filetest            =&gt; "-X",
    dereferencing       =&gt; '${} @{} %{} &amp;{} *{}',
    matching            =&gt; '~~',
    special             =&gt; 'nomethod fallback =',
);

my %ops_seen;
@ops_seen{ map split(/ /), values %ops } = ();

sub nil {}

sub OVERLOAD {
    my $package = shift;
    my %arg = @_;
    my $sub;
    *{$package . "::(("} = \&amp;nil; # Make it findable via fetchmethod.
    for (keys %arg) {
        if ($_ eq 'fallback') {
            for my $sym (*{$package . "::()"}) {
              *$sym = \&amp;nil; # Make it findable via fetchmethod.
              $$sym = $arg{$_};
            }
        } else {
            warnings::warnif("overload arg '$_' is invalid")
                unless exists $ops_seen{$_};
            $sub = $arg{$_};
            if (not ref $sub) {
                $ {$package . "::(" . $_} = $sub;
                $sub = \&amp;nil;
            }
            #print STDERR "Setting '$ {'package'}::\cO$_' to \\&amp;'$sub'.\n";
            *{$package . "::(" . $_} = \&amp;{ $sub };
        }
    }
}

sub import {
    my $package = caller();
    # *{$package . "::OVERLOAD"} = \&amp;OVERLOAD;
    shift;
    $package-&gt;overload::OVERLOAD(@_);
}

sub unimport {
    my $package = caller();
    shift;
    *{$package . "::(("} = \&amp;nil;
    for (@_) {
        warnings::warnif("overload arg '$_' is invalid")
            unless exists $ops_seen{$_};
        delete $ {$package . "::"}{$_ eq 'fallback' ? '()' : "(" .$_};
    }
}

sub Overloaded {
    my $package = shift;
    $package = ref $package if ref $package;
    mycan ($package, '()') || mycan ($package, '((');
}

sub ov_method {
    my $globref = shift;
    return undef unless $globref;
    my $sub = \&amp;{*$globref};
    no overloading;
    return $sub if $sub != \&amp;nil;
    return shift-&gt;can($ {*$globref});
}

sub OverloadedStringify {
    my $package = shift;
    $package = ref $package if ref $package;
    #$package-&gt;can('(""')
    ov_method mycan($package, '(""'), $package
        or ov_method mycan($package, '(0+'), $package
        or ov_method mycan($package, '(bool'), $package
        or ov_method mycan($package, '(nomethod'), $package;
}

sub Method {
    my $package = shift;
    if (ref $package) {
        no warnings 'experimental::builtin';
        $package = builtin::blessed($package);
        return undef if !defined $package;
    }
    #my $meth = $package-&gt;can('(' . shift);
    ov_method mycan($package, '(' . shift), $package;
    #return $meth if $meth ne \&amp;nil;
    #return $ {*{$meth}};
}

sub AddrRef {
    no overloading;
    "$_[0]";
}

*StrVal = *AddrRef;

sub mycan {                   # Real can would leave stubs.
    my ($package, $meth) = @_;

    local $@;
    local $!;
    require mro;

    my $mro = mro::get_linear_isa($package);
    foreach my $p (@$mro) {
        my $fqmeth = $p . q{::} . $meth;
        return \*{$fqmeth} if defined &amp;{$fqmeth};
    }

    return undef;
}

my %constants = (
    'integer'   =&gt;  0x1000, # HINT_NEW_INTEGER
    'float'     =&gt;  0x2000, # HINT_NEW_FLOAT
    'binary'    =&gt;  0x4000, # HINT_NEW_BINARY
    'q'         =&gt;  0x8000, # HINT_NEW_STRING
    'qr'        =&gt; 0x10000, # HINT_NEW_RE
);

use warnings::register;
sub constant {
    # Arguments: what, sub
    while (@_) {
        if (@_ == 1) {
            warnings::warnif ("Odd number of arguments for overload::constant");
            last;
        }
        elsif (!exists $constants {$_ [0]}) {
            warnings::warnif ("'$_[0]' is not an overloadable type");
        }
        elsif (!ref $_ [1] || "$_[1]" !~ /(^|=)CODE\(0x[0-9a-f]+\)$/) {
            # Can't use C&lt;ref $_[1] eq "CODE"&gt; above as code references can be
            # blessed, and C&lt;ref&gt; would return the package the ref is blessed into.
            if (warnings::enabled) {
                $_ [1] = "undef" unless defined $_ [1];
                warnings::warn ("'$_[1]' is not a code reference");
            }
        }
        else {
            $^H{$_[0]} = $_[1];
            $^H |= $constants{$_[0]};
        }
        shift, shift;
    }
}

sub remove_constant {
    # Arguments: what, sub
    while (@_) {
        delete $^H{$_[0]};
        $^H &amp;= ~ $constants{$_[0]};
        shift, shift;
    }
}

1;

__END__

=head1 NAME

overload - Package for overloading Perl operations

=head1 SYNOPSIS

    package SomeThing;

    use overload
        '+' =&gt; \&amp;myadd,
        '-' =&gt; \&amp;mysub;
        # etc
    ...

    package main;
    $a = SomeThing-&gt;new( 57 );
    $b = 5 + $a;
    ...
    if (overload::Overloaded $b) {...}
    ...
    $strval = overload::StrVal $b;

=head1 DESCRIPTION

This pragma allows overloading of Perl's operators for a class.
To overload built-in functions, see L&lt;perlsub/Overriding Built-in Functions&gt; instead.

=head2 Fundamentals

=head3 Declaration

Arguments of the C&lt;use overload&gt; directive are (key, value) pairs.
For the full set of legal keys, see L&lt;/Overloadable Operations&gt; below.

Operator implementations (the values) can be subroutines,
references to subroutines, or anonymous subroutines
- in other words, anything legal inside a C&lt;&amp;{ ... }&gt; call.
Values specified as strings are interpreted as method names.
Thus

    package Number;
    use overload
        "-" =&gt; "minus",
        "*=" =&gt; \&amp;muas,
        '""' =&gt; sub { ...; };

declares that subtraction is to be implemented by method C&lt;minus()&gt;
in the class C&lt;Number&gt; (or one of its base classes),
and that the function C&lt;Number::muas()&gt; is to be used for the
assignment form of multiplication, C&lt;*=&gt;.
It also defines an anonymous subroutine to implement stringification:
this is called whenever an object blessed into the package C&lt;Number&gt;
is used in a string context (this subroutine might, for example,
return the number as a Roman numeral).

=head3 Calling Conventions and Magic Autogeneration

The following sample implementation of C&lt;minus()&gt; (which assumes
that C&lt;Number&gt; objects are simply blessed references to scalars)
illustrates the calling conventions:

    package Number;
    sub minus {
        my ($self, $other, $swap) = @_;
        my $result = $$self - $other;         # *
        $result = -$result if $swap;
        ref $result ? $result : bless \$result;
    }
    # * may recurse once - see table below

Three arguments are passed to all subroutines specified in the
C&lt;use overload&gt; directive (with exceptions - see below, particularly
L&lt;/nomethod&gt;).

The first of these is the operand providing the overloaded
operator implementation -
in this case, the object whose C&lt;minus()&gt; method is being called.

The second argument is the other operand, or C&lt;undef&gt; in the
case of a unary operator.

The third argument is set to TRUE if (and only if) the two
operands have been swapped.  Perl may do this to ensure that the
first argument (C&lt;$self&gt;) is an object implementing the overloaded
operation, in line with general object calling conventions.
For example, if C&lt;$x&gt; and C&lt;$y&gt; are C&lt;Number&gt;s:

    operation   |   generates a call to
    ============|======================
    $x - $y     |   minus($x, $y, '')
    $x - 7      |   minus($x, 7, '')
    7 - $x      |   minus($x, 7, 1)

Perl may also use C&lt;minus()&gt; to implement other operators which
have not been specified in the C&lt;use overload&gt; directive,
according to the rules for L&lt;/Magic Autogeneration&gt; described later.
For example, the C&lt;use overload&gt; above declared no subroutine
for any of the operators C&lt;--&gt;, C&lt;neg&gt; (the overload key for
unary minus), or C&lt;-=&gt;.  Thus

    operation   |   generates a call to
    ============|======================
    -$x         |   minus($x, 0, 1)
    $x--        |   minus($x, 1, undef)
    $x -= 3     |   minus($x, 3, undef)

Note the C&lt;undef&gt;s:
where autogeneration results in the method for a standard
operator which does not change either of its operands, such
as C&lt;-&gt;, being used to implement an operator which changes
the operand ("mutators": here, C&lt;--&gt; and C&lt;-=&gt;),
Perl passes undef as the third argument.
This still evaluates as FALSE, consistent with the fact that
the operands have not been swapped, but gives the subroutine
a chance to alter its behaviour in these cases.

In all the above examples, C&lt;minus()&gt; is required
only to return the result of the subtraction:
Perl takes care of the assignment to $x.
In fact, such methods should I&lt;not&gt; modify their operands,
even if C&lt;undef&gt; is passed as the third argument
(see L&lt;/Overloadable Operations&gt;).

The same is not true of implementations of C&lt;++&gt; and C&lt;--&gt;:
these are expected to modify their operand.
An appropriate implementation of C&lt;--&gt; might look like

    use overload '--' =&gt; "decr",
        # ...
    sub decr { --${$_[0]}; }

If the "bitwise" feature is enabled (see L&lt;feature&gt;), a fifth
TRUE argument is passed to subroutines handling C&lt;&amp;&gt;, C&lt;|&gt;, C&lt;^&gt; and C&lt;~&gt;.
This indicates that the caller is expecting numeric behaviour.  The fourth
argument will be C&lt;undef&gt;, as that position (C&lt;$_[3]&gt;) is reserved for use
by L&lt;/nomethod&gt;.

=head3 Mathemagic, Mutators, and Copy Constructors

The term 'mathemagic' describes the overloaded implementation
of mathematical operators.
Mathemagical operations raise an issue.
Consider the code:

    $a = $b;
    --$a;

If C&lt;$a&gt; and C&lt;$b&gt; are scalars then after these statements

    $a == $b - 1

An object, however, is a reference to blessed data, so if
C&lt;$a&gt; and C&lt;$b&gt; are objects then the assignment C&lt;$a = $b&gt;
copies only the reference, leaving C&lt;$a&gt; and C&lt;$b&gt; referring
to the same object data.
One might therefore expect the operation C&lt;--$a&gt; to decrement
C&lt;$b&gt; as well as C&lt;$a&gt;.
However, this would not be consistent with how we expect the
mathematical operators to work.

Perl resolves this dilemma by transparently calling a copy
constructor before calling a method defined to implement
a mutator (C&lt;--&gt;, C&lt;+=&gt;, and so on.).
In the above example, when Perl reaches the decrement
statement, it makes a copy of the object data in C&lt;$a&gt; and
assigns to C&lt;$a&gt; a reference to the copied data.
Only then does it call C&lt;decr()&gt;, which alters the copied
data, leaving C&lt;$b&gt; unchanged.
Thus the object metaphor is preserved as far as possible,
while mathemagical operations still work according to the
arithmetic metaphor.

Note: the preceding paragraph describes what happens when
Perl autogenerates the copy constructor for an object based
on a scalar.
For other cases, see L&lt;/Copy Constructor&gt;.

=head2 Overloadable Operations

The complete list of keys that can be specified in the C&lt;use overload&gt;
directive are given, separated by spaces, in the values of the
hash C&lt;%overload::ops&gt;:

    with_assign         =&gt; '+ - * / % ** &lt;&lt; &gt;&gt; x .',
    assign              =&gt; '+= -= *= /= %= **= &lt;&lt;= &gt;&gt;= x= .=',
    num_comparison      =&gt; '&lt; &lt;= &gt; &gt;= == !=',
    '3way_comparison'   =&gt; '&lt;=&gt; cmp',
    str_comparison      =&gt; 'lt le gt ge eq ne',
    binary              =&gt; '&amp; &amp;= | |= ^ ^= &amp;. &amp;.= |. |.= ^. ^.=',
    unary               =&gt; 'neg ! ~ ~.',
    mutators            =&gt; '++ --',
    func                =&gt; 'atan2 cos sin exp abs log sqrt int',
    conversion          =&gt; 'bool "" 0+ qr',
    iterators           =&gt; '&lt;&gt;',
    filetest            =&gt; '-X',
    dereferencing       =&gt; '${} @{} %{} &amp;{} *{}',
    matching            =&gt; '~~',
    special             =&gt; 'nomethod fallback =',

Most of the overloadable operators map one-to-one to these keys.
Exceptions, including additional overloadable operations not
apparent from this hash, are included in the notes which follow.
This list is subject to growth over time.

A warning is issued if an attempt is made to register an operator not found
above.

=over 5

=item * C&lt;not&gt;

The operator C&lt;not&gt; is not a valid key for C&lt;use overload&gt;.
However, if the operator C&lt;!&gt; is overloaded then the same
implementation will be used for C&lt;not&gt;
(since the two operators differ only in precedence).

=item * C&lt;neg&gt;

The key C&lt;neg&gt; is used for unary minus to disambiguate it from
binary C&lt;-&gt;.

=item * C&lt;++&gt;, C&lt;--&gt;

Assuming they are to behave analogously to Perl's C&lt;++&gt; and C&lt;--&gt;,
overloaded implementations of these operators are required to
mutate their operands.

No distinction is made between prefix and postfix forms of the
increment and decrement operators: these differ only in the
point at which Perl calls the associated subroutine when
evaluating an expression.

=item * I&lt;Assignments&gt;

    +=  -=  *=  /=  %=  **=  &lt;&lt;=  &gt;&gt;=  x=  .=
    &amp;=  |=  ^=  &amp;.=  |.=  ^.=

Simple assignment is not overloadable (the C&lt;'='&gt; key is used
for the L&lt;/Copy Constructor&gt;).
Perl does have a way to make assignments to an object do whatever
you want, but this involves using tie(), not overload -
see L&lt;perlfunc/tie&gt; and the L&lt;/COOKBOOK&gt; examples below.

The subroutine for the assignment variant of an operator is
required only to return the result of the operation.
It is permitted to change the value of its operand
(this is safe because Perl calls the copy constructor first),
but this is optional since Perl assigns the returned value to
the left-hand operand anyway.

An object that overloads an assignment operator does so only in
respect of assignments to that object.
In other words, Perl never calls the corresponding methods with
the third argument (the "swap" argument) set to TRUE.
For example, the operation

    $a *= $b

cannot lead to C&lt;$b&gt;'s implementation of C&lt;*=&gt; being called,
even if C&lt;$a&gt; is a scalar.
(It can, however, generate a call to C&lt;$b&gt;'s method for C&lt;*&gt;).

=item * I&lt;Non-mutators with a mutator variant&gt;

     +  -  *  /  %  **  &lt;&lt;  &gt;&gt;  x  .
     &amp;  |  ^  &amp;.  |.  ^.

As described L&lt;above|"Calling Conventions and Magic Autogeneration"&gt;,
Perl may call methods for operators like C&lt;+&gt; and C&lt;&amp;&gt; in the course
of implementing missing operations like C&lt;++&gt;, C&lt;+=&gt;, and C&lt;&amp;=&gt;.
While these methods may detect this usage by testing the definedness
of the third argument, they should in all cases avoid changing their
operands.
This is because Perl does not call the copy constructor before
invoking these methods.

=item * C&lt;int&gt;

Traditionally, the Perl function C&lt;int&gt; rounds to 0
(see L&lt;perlfunc/int&gt;), and so for floating-point-like types one
should follow the same semantic.

=item * I&lt;String, numeric, boolean, and regexp conversions&gt;

    ""  0+  bool

These conversions are invoked according to context as necessary.
For example, the subroutine for C&lt;'""'&gt; (stringify) may be used
where the overloaded object is passed as an argument to C&lt;print&gt;,
and that for C&lt;'bool'&gt; where it is tested in the condition of a flow
control statement (like C&lt;while&gt;) or the ternary C&lt;?:&gt; operation.

Of course, in contexts like, for example, C&lt;$obj + 1&gt;, Perl will
invoke C&lt;$obj&gt;'s implementation of C&lt;+&gt; rather than (in this
example) converting C&lt;$obj&gt; to a number using the numify method
C&lt;'0+'&gt; (an exception to this is when no method has been provided
for C&lt;'+'&gt; and L&lt;/fallback&gt; is set to TRUE).

The subroutines for C&lt;'""'&gt;, C&lt;'0+'&gt;, and C&lt;'bool'&gt; can return
any arbitrary Perl value.
If the corresponding operation for this value is overloaded too,
the operation will be called again with this value.

As a special case if the overload returns the object itself then it will
be used directly.  An overloaded conversion returning the object is
probably a bug, because you're likely to get something that looks like
C&lt;YourPackage=HASH(0x8172b34)&gt;.

    qr

The subroutine for C&lt;'qr'&gt; is used wherever the object is
interpolated into or used as a regexp, including when it
appears on the RHS of a C&lt;=~&gt; or C&lt;!~&gt; operator.

C&lt;qr&gt; must return a compiled regexp, or a ref to a compiled regexp
(such as C&lt;qr//&gt; returns), and any further overloading on the return
value will be ignored.

=item * I&lt;Iteration&gt;

If C&lt;E&lt;lt&gt;E&lt;gt&gt;&gt; is overloaded then the same implementation is used
for both the I&lt;read-filehandle&gt; syntax C&lt;E&lt;lt&gt;$varE&lt;gt&gt;&gt; and
I&lt;globbing&gt; syntax C&lt;E&lt;lt&gt;${var}E&lt;gt&gt;&gt;.

=item * I&lt;File tests&gt;

The key C&lt;'-X'&gt; is used to specify a subroutine to handle all the
filetest operators (C&lt;-f&gt;, C&lt;-x&gt;, and so on: see L&lt;perlfunc/-X&gt; for
the full list);
it is not possible to overload any filetest operator individually.
To distinguish them, the letter following the '-' is passed as the
second argument (that is, in the slot that for binary operators
is used to pass the second operand).

Calling an overloaded filetest operator does not affect the stat value
associated with the special filehandle C&lt;_&gt;.  It still refers to the
result of the last C&lt;stat&gt;, C&lt;lstat&gt; or unoverloaded filetest.

This overload was introduced in Perl 5.12.

=item * I&lt;Matching&gt;

The key C&lt;"~~"&gt; allows you to override the smart matching logic used by
the C&lt;~~&gt; operator and the switch construct (C&lt;given&gt;/C&lt;when&gt;).  See
L&lt;perlsyn/Switch Statements&gt; and L&lt;feature&gt;.

Unusually, the overloaded implementation of the smart match operator
does not get full control of the smart match behaviour.
In particular, in the following code:

    package Foo;
    use overload '~~' =&gt; 'match';

    my $obj =  Foo-&gt;new();
    $obj ~~ [ 1,2,3 ];

the smart match does I&lt;not&gt; invoke the method call like this:

    $obj-&gt;match([1,2,3],0);

rather, the smart match distributive rule takes precedence, so $obj is
smart matched against each array element in turn until a match is found,
so you may see between one and three of these calls instead:

    $obj-&gt;match(1,0);
    $obj-&gt;match(2,0);
    $obj-&gt;match(3,0);

Consult the match table in  L&lt;perlop/"Smartmatch Operator"&gt; for
details of when overloading is invoked.

=item * I&lt;Dereferencing&gt;

    ${}  @{}  %{}  &amp;{}  *{}

If these operators are not explicitly overloaded then they
work in the normal way, yielding the underlying scalar,
array, or whatever stores the object data (or the appropriate
error message if the dereference operator doesn't match it).
Defining a catch-all C&lt;'nomethod'&gt; (see L&lt;below|/nomethod&gt;)
makes no difference to this as the catch-all function will
not be called to implement a missing dereference operator.

If a dereference operator is overloaded then it must return a
I&lt;reference&gt; of the appropriate type (for example, the
subroutine for key C&lt;'${}'&gt; should return a reference to a
scalar, not a scalar), or another object which overloads the
operator: that is, the subroutine only determines what is
dereferenced and the actual dereferencing is left to Perl.
As a special case, if the subroutine returns the object itself
then it will not be called again - avoiding infinite recursion.

=item * I&lt;Special&gt;

    nomethod  fallback  =

See L&lt;/Special Keys for C&lt;use overload&gt;&gt;.

=back

=head2 Magic Autogeneration

If a method for an operation is not found then Perl tries to
autogenerate a substitute implementation from the operations
that have been defined.

Note: the behaviour described in this section can be disabled
by setting C&lt;fallback&gt; to FALSE (see L&lt;/fallback&gt;).

In the following tables, numbers indicate priority.
For example, the table below states that,
if no implementation for C&lt;'!'&gt; has been defined then Perl will
implement it using C&lt;'bool'&gt; (that is, by inverting the value
returned by the method for C&lt;'bool'&gt;);
if boolean conversion is also unimplemented then Perl will
use C&lt;'0+'&gt; or, failing that, C&lt;'""'&gt;.

    operator | can be autogenerated from
             |
             | 0+   ""   bool   .   x
    =========|==========================
       0+    |       1     2
       ""    |  1          2
       bool  |  1    2
       int   |  1    2     3
       !     |  2    3     1
       qr    |  2    1     3
       .     |  2    1     3
       x     |  2    1     3
       .=    |  3    2     4    1
       x=    |  3    2     4        1
       &lt;&gt;    |  2    1     3
       -X    |  2    1     3

Note: The iterator (C&lt;'E&lt;lt&gt;E&lt;gt&gt;'&gt;) and file test (C&lt;'-X'&gt;)
operators work as normal: if the operand is not a blessed glob or
IO reference then it is converted to a string (using the method
for C&lt;'""'&gt;, C&lt;'0+'&gt;, or C&lt;'bool'&gt;) to be interpreted as a glob
or filename.

    operator | can be autogenerated from
             |
             |  &lt;   &lt;=&gt;   neg   -=    -
    =========|==========================
       neg   |                        1
       -=    |                        1
       --    |                   1    2
       abs   | a1    a2    b1        b2    [*]
       &lt;     |        1
       &lt;=    |        1
       &gt;     |        1
       &gt;=    |        1
       ==    |        1
       !=    |        1

    * one from [a1, a2] and one from [b1, b2]

Just as numeric comparisons can be autogenerated from the method
for C&lt;&lt; '&lt;=&gt;' &gt;&gt;, string comparisons can be autogenerated from
that for C&lt;'cmp'&gt;:

     operators          |  can be autogenerated from
    ====================|===========================
     lt gt le ge eq ne  |  cmp

Similarly, autogeneration for keys C&lt;'+='&gt; and C&lt;'++'&gt; is analogous
to C&lt;'-='&gt; and C&lt;'--'&gt; above:

    operator | can be autogenerated from
             |
             |  +=    +
    =========|==========================
        +=   |        1
        ++   |   1    2

And other assignment variations are analogous to
C&lt;'+='&gt; and C&lt;'-='&gt; (and similar to C&lt;'.='&gt; and C&lt;'x='&gt; above):

              operator ||  *= /= %= **= &lt;&lt;= &gt;&gt;= &amp;= ^= |= &amp;.= ^.= |.=
    -------------------||-------------------------------------------
    autogenerated from ||  *  /  %  **  &lt;&lt;  &gt;&gt;  &amp;  ^  |  &amp;.  ^.  |.

Note also that the copy constructor (key C&lt;'='&gt;) may be
autogenerated, but only for objects based on scalars.
See L&lt;/Copy Constructor&gt;.

=head3 Minimal Set of Overloaded Operations

Since some operations can be automatically generated from others, there is
a minimal set of operations that need to be overloaded in order to have
the complete set of overloaded operations at one's disposal.
Of course, the autogenerated operations may not do exactly what the user
expects.  The minimal set is:

    + - * / % ** &lt;&lt; &gt;&gt; x
    &lt;=&gt; cmp
    &amp; | ^ ~ &amp;. |. ^. ~.
    atan2 cos sin exp log sqrt int
    "" 0+ bool
    ~~

Of the conversions, only one of string, boolean or numeric is
needed because each can be generated from either of the other two.

=head2 Special Keys for C&lt;use overload&gt;

=head3 C&lt;nomethod&gt;

The C&lt;'nomethod'&gt; key is used to specify a catch-all function to
be called for any operator that is not individually overloaded.
The specified function will be passed four parameters.
The first three arguments coincide with those that would have been
passed to the corresponding method if it had been defined.
The fourth argument is the C&lt;use overload&gt; key for that missing
method.  If the "bitwise" feature is enabled (see L&lt;feature&gt;),
a fifth TRUE argument is passed to subroutines handling C&lt;&amp;&gt;, C&lt;|&gt;, C&lt;^&gt; and C&lt;~&gt; to indicate that the caller is expecting numeric behaviour.

For example, if C&lt;$a&gt; is an object blessed into a package declaring

    use overload 'nomethod' =&gt; 'catch_all', # ...

then the operation

    3 + $a

could (unless a method is specifically declared for the key
C&lt;'+'&gt;) result in a call

    catch_all($a, 3, 1, '+')

See L&lt;/How Perl Chooses an Operator Implementation&gt;.

=head3 C&lt;fallback&gt;

The value assigned to the key C&lt;'fallback'&gt; tells Perl how hard
it should try to find an alternative way to implement a missing
operator.

=over

=item * defined, but FALSE

    use overload "fallback" =&gt; 0, # ... ;

This disables L&lt;/Magic Autogeneration&gt;.

=item * C&lt;undef&gt;

In the default case where no value is explicitly assigned to
C&lt;fallback&gt;, magic autogeneration is enabled.

=item * TRUE

The same as for C&lt;undef&gt;, but if a missing operator cannot be
autogenerated then, instead of issuing an error message, Perl
is allowed to revert to what it would have done for that
operator if there had been no C&lt;use overload&gt; directive.

Note: in most cases, particularly the L&lt;/Copy Constructor&gt;,
this is unlikely to be appropriate behaviour.

=back

See L&lt;/How Perl Chooses an Operator Implementation&gt;.

=head3 Copy Constructor

As mentioned L&lt;above|"Mathemagic, Mutators, and Copy Constructors"&gt;,
this operation is called when a mutator is applied to a reference
that shares its object with some other reference.
For example, if C&lt;$b&gt; is mathemagical, and C&lt;'++'&gt; is overloaded
with C&lt;'incr'&gt;, and C&lt;'='&gt; is overloaded with C&lt;'clone'&gt;, then the
code

    $a = $b;
    # ... (other code which does not modify $a or $b) ...
    ++$b;

would be executed in a manner equivalent to

    $a = $b;
    # ...
    $b = $b-&gt;clone(undef, "");
    $b-&gt;incr(undef, "");

Note:

=over

=item *

The subroutine for C&lt;'='&gt; does not overload the Perl assignment
operator: it is used only to allow mutators to work as described
here.  (See L&lt;/Assignments&gt; above.)

=item *

As for other operations, the subroutine implementing '=' is passed
three arguments, though the last two are always C&lt;undef&gt; and C&lt;''&gt;.

=item *

The copy constructor is called only before a call to a function
declared to implement a mutator, for example, if C&lt;++$b;&gt; in the
code above is effected via a method declared for key C&lt;'++'&gt;
(or 'nomethod', passed C&lt;'++'&gt; as the fourth argument) or, by
autogeneration, C&lt;'+='&gt;.
It is not called if the increment operation is effected by a call
to the method for C&lt;'+'&gt; since, in the equivalent code,

    $a = $b;
    $b = $b + 1;

the data referred to by C&lt;$a&gt; is unchanged by the assignment to
C&lt;$b&gt; of a reference to new object data.

=item *

The copy constructor is not called if Perl determines that it is
unnecessary because there is no other reference to the data being
modified.

=item *

If C&lt;'fallback'&gt; is undefined or TRUE then a copy constructor
can be autogenerated, but only for objects based on scalars.
In other cases it needs to be defined explicitly.
Where an object's data is stored as, for example, an array of
scalars, the following might be appropriate:

    use overload '=' =&gt; sub { bless [ @{$_[0]} ] },  # ...

=item *

If C&lt;'fallback'&gt; is TRUE and no copy constructor is defined then,
for objects not based on scalars, Perl may silently fall back on
simple assignment - that is, assignment of the object reference.
In effect, this disables the copy constructor mechanism since
no new copy of the object data is created.
This is almost certainly not what you want.
(It is, however, consistent: for example, Perl's fallback for the
C&lt;++&gt; operator is to increment the reference itself.)

=back

=head2 How Perl Chooses an Operator Implementation

Which is checked first, C&lt;nomethod&gt; or C&lt;fallback&gt;?
If the two operands of an operator are of different types and
both overload the operator, which implementation is used?
The following are the precedence rules:

=over

=item 1.

If the first operand has declared a subroutine to overload the
operator then use that implementation.

=item 2.

Otherwise, if fallback is TRUE or undefined for the
first operand then see if the
L&lt;rules for autogeneration|"Magic Autogeneration"&gt;
allows another of its operators to be used instead.

=item 3.

Unless the operator is an assignment (C&lt;+=&gt;, C&lt;-=&gt;, etc.),
repeat step (1) in respect of the second operand.

=item 4.

Repeat Step (2) in respect of the second operand.

=item 5.

If the first operand has a "nomethod" method then use that.

=item 6.

If the second operand has a "nomethod" method then use that.

=item 7.

If C&lt;fallback&gt; is TRUE for both operands
then perform the usual operation for the operator,
treating the operands as numbers, strings, or booleans
as appropriate for the operator (see note).

=item 8.

Nothing worked - die.

=back

Where there is only one operand (or only one operand with
overloading) the checks in respect of the other operand above are
skipped.

There are exceptions to the above rules for dereference operations
(which, if Step 1 fails, always fall back to the normal, built-in
implementations - see Dereferencing), and for C&lt;~~&gt; (which has its
own set of rules - see C&lt;Matching&gt; under L&lt;/Overloadable Operations&gt;
above).

Note on Step 7: some operators have a different semantic depending
on the type of their operands.
As there is no way to instruct Perl to treat the operands as, e.g.,
numbers instead of strings, the result here may not be what you
expect.
See L&lt;/BUGS AND PITFALLS&gt;.

=head2 Losing Overloading

The restriction for the comparison operation is that even if, for example,
C&lt;cmp&gt; should return a blessed reference, the autogenerated C&lt;lt&gt;
function will produce only a standard logical value based on the
numerical value of the result of C&lt;cmp&gt;.  In particular, a working
numeric conversion is needed in this case (possibly expressed in terms of
other conversions).

Similarly, C&lt;.=&gt;  and C&lt;x=&gt; operators lose their mathemagical properties
if the string conversion substitution is applied.

When you chop() a mathemagical object it is promoted to a string and its
mathemagical properties are lost.  The same can happen with other
operations as well.

=head2 Inheritance and Overloading

Overloading respects inheritance via the @ISA hierarchy.
Inheritance interacts with overloading in two ways.

=over

=item Method names in the C&lt;use overload&gt; directive

If C&lt;value&gt; in

    use overload key =&gt; value;

is a string, it is interpreted as a method name - which may
(in the usual way) be inherited from another class.

=item Overloading of an operation is inherited by derived classes

Any class derived from an overloaded class is also overloaded
and inherits its operator implementations.
If the same operator is overloaded in more than one ancestor
then the implementation is determined by the usual inheritance
rules.

For example, if C&lt;A&gt; inherits from C&lt;B&gt; and C&lt;C&gt; (in that order),
C&lt;B&gt; overloads C&lt;+&gt; with C&lt;\&amp;D::plus_sub&gt;, and C&lt;C&gt; overloads
C&lt;+&gt; by C&lt;"plus_meth"&gt;, then the subroutine C&lt;D::plus_sub&gt; will
be called to implement operation C&lt;+&gt; for an object in package C&lt;A&gt;.

=back

Note that in Perl version prior to 5.18 inheritance of the C&lt;fallback&gt; key
was not governed by the above rules.  The value of C&lt;fallback&gt; in the first
overloaded ancestor was used.  This was fixed in 5.18 to follow the usual
rules of inheritance.

=head2 Run-time Overloading

Since all C&lt;use&gt; directives are executed at compile-time, the only way to
change overloading during run-time is to

    eval 'use overload "+" =&gt; \&amp;addmethod';

You can also use

    eval 'no overload "+", "--", "&lt;="';

though the use of these constructs during run-time is questionable.

=head2 Public Functions

Package C&lt;overload.pm&gt; provides the following public functions:

=over 5

=item overload::StrVal(arg)

Gives the string value of C&lt;arg&gt; as in the
absence of stringify overloading.  If you
are using this to get the address of a reference (useful for checking if two
references point to the same thing) then you may be better off using
C&lt;builtin::refaddr()&gt; or C&lt;Scalar::Util::refaddr()&gt;, which are faster.

=item overload::Overloaded(arg)

Returns true if C&lt;arg&gt; is subject to overloading of some operations.

=item overload::Method(obj,op)

Returns C&lt;undef&gt; or a reference to the method that implements C&lt;op&gt;.

Such a method always takes three arguments, which will be enforced if
it is an XS method.

=back

=head2 Overloading Constants

For some applications, the Perl parser mangles constants too much.
It is possible to hook into this process via C&lt;overload::constant()&gt;
and C&lt;overload::remove_constant()&gt; functions.

These functions take a hash as an argument.  The recognized keys of this hash
are:

=over 8

=item integer

to overload integer constants,

=item float

to overload floating point constants,

=item binary

to overload octal and hexadecimal constants,

=item q

to overload C&lt;q&gt;-quoted strings, constant pieces of C&lt;qq&gt;- and C&lt;qx&gt;-quoted
strings and here-documents,

=item qr

to overload constant pieces of regular expressions.

=back

The corresponding values are references to functions which take three arguments:
the first one is the I&lt;initial&gt; string form of the constant, the second one
is how Perl interprets this constant, the third one is how the constant is used.
Note that the initial string form does not
contain string delimiters, and has backslashes in backslash-delimiter
combinations stripped (thus the value of delimiter is not relevant for
processing of this string).  The return value of this function is how this
constant is going to be interpreted by Perl.  The third argument is undefined
unless for overloaded C&lt;q&gt;- and C&lt;qr&gt;- constants, it is C&lt;q&gt; in single-quote
context (comes from strings, regular expressions, and single-quote HERE
documents), it is C&lt;tr&gt; for arguments of C&lt;tr&gt;/C&lt;y&gt; operators,
it is C&lt;s&gt; for right-hand side of C&lt;s&gt;-operator, and it is C&lt;qq&gt; otherwise.

Since an expression C&lt;"ab$cd,,"&gt; is just a shortcut for C&lt;'ab' . $cd . ',,'&gt;,
it is expected that overloaded constant strings are equipped with reasonable
overloaded catenation operator, otherwise absurd results will result.
Similarly, negative numbers are considered as negations of positive constants.

Note that it is probably meaningless to call the functions overload::constant()
and overload::remove_constant() from anywhere but import() and unimport() methods.
From these methods they may be called as

    sub import {
        shift;
        return unless @_;
        die "unknown import: @_" unless @_ == 1 and $_[0] eq ':constant';
        overload::constant integer =&gt; sub {Math::BigInt-&gt;new(shift)};
    }

=head1 IMPLEMENTATION

What follows is subject to change RSN.

The table of methods for all operations is cached in magic for the
symbol table hash for the package.  The cache is invalidated during
processing of C&lt;use overload&gt;, C&lt;no overload&gt;, new function
definitions, and changes in @ISA.

(Every SVish thing has a magic queue, and magic is an entry in that
queue.  This is how a single variable may participate in multiple
forms of magic simultaneously.  For instance, environment variables
regularly have two forms at once: their %ENV magic and their taint
magic.  However, the magic which implements overloading is applied to
the stashes, which are rarely used directly, thus should not slow down
Perl.)

If a package uses overload, it carries a special flag.  This flag is also
set when new functions are defined or @ISA is modified.  There will be a
slight speed penalty on the very first operation thereafter that supports
overloading, while the overload tables are updated.  If there is no
overloading present, the flag is turned off.  Thus the only speed penalty
thereafter is the checking of this flag.

It is expected that arguments to methods that are not explicitly supposed
to be changed are constant (but this is not enforced).

=head1 COOKBOOK

Please add examples to what follows!

=head2 Two-face Scalars

Put this in F&lt;two_face.pm&gt; in your Perl library directory:

    package two_face;             # Scalars with separate string and
                                  # numeric values.
    sub new { my $p = shift; bless [@_], $p }
    use overload '""' =&gt; \&amp;str, '0+' =&gt; \&amp;num, fallback =&gt; 1;
    sub num {shift-&gt;[1]}
    sub str {shift-&gt;[0]}

Use it as follows:

    require two_face;
    my $seven = two_face-&gt;new("vii", 7);
    printf "seven=$seven, seven=%d, eight=%d\n", $seven, $seven+1;
    print "seven contains 'i'\n" if $seven =~ /i/;

(The second line creates a scalar which has both a string value, and a
numeric value.)  This prints:

    seven=vii, seven=7, eight=8
    seven contains 'i'

=head2 Two-face References

Suppose you want to create an object which is accessible as both an
array reference and a hash reference.

    package two_refs;
    use overload '%{}' =&gt; \&amp;gethash, '@{}' =&gt; sub { $ {shift()} };
    sub new {
        my $p = shift;
        bless \ [@_], $p;
    }
    sub gethash {
        my %h;
        my $self = shift;
        tie %h, ref $self, $self;
        \%h;
    }

    sub TIEHASH { my $p = shift; bless \ shift, $p }
    my %fields;
    my $i = 0;
    $fields{$_} = $i++ foreach qw{zero one two three};
    sub STORE {
        my $self = ${shift()};
        my $key = $fields{shift()};
        defined $key or die "Out of band access";
        $$self-&gt;[$key] = shift;
    }
    sub FETCH {
        my $self = ${shift()};
        my $key = $fields{shift()};
        defined $key or die "Out of band access";
        $$self-&gt;[$key];
    }

Now one can access an object using both the array and hash syntax:

    my $bar = two_refs-&gt;new(3,4,5,6);
    $bar-&gt;[2] = 11;
    $bar-&gt;{two} == 11 or die 'bad hash fetch';

Note several important features of this example.  First of all, the
I&lt;actual&gt; type of $bar is a scalar reference, and we do not overload
the scalar dereference.  Thus we can get the I&lt;actual&gt; non-overloaded
contents of $bar by just using C&lt;$$bar&gt; (what we do in functions which
overload dereference).  Similarly, the object returned by the
TIEHASH() method is a scalar reference.

Second, we create a new tied hash each time the hash syntax is used.
This allows us not to worry about a possibility of a reference loop,
which would lead to a memory leak.

Both these problems can be cured.  Say, if we want to overload hash
dereference on a reference to an object which is I&lt;implemented&gt; as a
hash itself, the only problem one has to circumvent is how to access
this I&lt;actual&gt; hash (as opposed to the I&lt;virtual&gt; hash exhibited by the
overloaded dereference operator).  Here is one possible fetching routine:

    sub access_hash {
        my ($self, $key) = (shift, shift);
        my $class = ref $self;
        bless $self, 'overload::dummy'; # Disable overloading of %{}
        my $out = $self-&gt;{$key};
        bless $self, $class;            # Restore overloading
        $out;
    }

To remove creation of the tied hash on each access, one may an extra
level of indirection which allows a non-circular structure of references:

    package two_refs1;
    use overload
        '%{}' =&gt; sub { ${shift()}-&gt;[1] },
        '@{}' =&gt; sub { ${shift()}-&gt;[0] };

    sub new {
        my $p = shift;
        my $a = [@_];
        my %h;
        tie %h, $p, $a;
        bless \ [$a, \%h], $p;
    }
    sub gethash {
        my %h;
        my $self = shift;
        tie %h, ref $self, $self;
        \%h;
    }

    sub TIEHASH { my $p = shift; bless \ shift, $p }
    my %fields;
    my $i = 0;
    $fields{$_} = $i++ foreach qw{zero one two three};
    sub STORE {
        my $a = ${shift()};
        my $key = $fields{shift()};
        defined $key or die "Out of band access";
        $a-&gt;[$key] = shift;
    }
    sub FETCH {
        my $a = ${shift()};
        my $key = $fields{shift()};
        defined $key or die "Out of band access";
        $a-&gt;[$key];
    }

Now if $baz is overloaded like this, then C&lt;$baz&gt; is a reference to a
reference to the intermediate array, which keeps a reference to an
actual array, and the access hash.  The tie()ing object for the access
hash is a reference to a reference to the actual array, so

=over

=item *

There are no loops of references.

=item *

Both "objects" which are blessed into the class C&lt;two_refs1&gt; are
references to a reference to an array, thus references to a I&lt;scalar&gt;.
Thus the accessor expression C&lt;$$foo-E&lt;gt&gt;[$ind]&gt; involves no
overloaded operations.

=back

=head2 Symbolic Calculator

Put this in F&lt;symbolic.pm&gt; in your Perl library directory:

    package symbolic;           # Primitive symbolic calculator
    use overload nomethod =&gt; \&amp;wrap;

    sub new { shift; bless ['n', @_] }
    sub wrap {
        my ($obj, $other, $inv, $meth) = @_;
        ($obj, $other) = ($other, $obj) if $inv;
        bless [$meth, $obj, $other];
    }

This module is very unusual as overloaded modules go: it does not
provide any usual overloaded operators, instead it provides an
implementation for C&lt;L&lt;/nomethod&gt;&gt;.  In this example the C&lt;nomethod&gt;
subroutine returns an object which encapsulates operations done over
the objects: C&lt;&lt; symbolic-&gt;new(3) &gt;&gt; contains C&lt;['n', 3]&gt;, C&lt;&lt; 2 +
symbolic-&gt;new(3) &gt;&gt; contains C&lt;['+', 2, ['n', 3]]&gt;.

Here is an example of the script which "calculates" the side of
circumscribed octagon using the above package:

    require symbolic;
    my $iter = 1;                   # 2**($iter+2) = 8
    my $side = symbolic-&gt;new(1);
    my $cnt = $iter;

    while ($cnt--) {
        $side = (sqrt(1 + $side**2) - 1)/$side;
    }
    print "OK\n";

The value of $side is

    ['/', ['-', ['sqrt', ['+', 1, ['**', ['n', 1], 2]],
                        undef], 1], ['n', 1]]

Note that while we obtained this value using a nice little script,
there is no simple way to I&lt;use&gt; this value.  In fact this value may
be inspected in debugger (see L&lt;perldebug&gt;), but only if
C&lt;bareStringify&gt; B&lt;O&gt;ption is set, and not via C&lt;p&gt; command.

If one attempts to print this value, then the overloaded operator
C&lt;""&gt; will be called, which will call C&lt;nomethod&gt; operator.  The
result of this operator will be stringified again, but this result is
again of type C&lt;symbolic&gt;, which will lead to an infinite loop.

Add a pretty-printer method to the module F&lt;symbolic.pm&gt;:

    sub pretty {
        my ($meth, $a, $b) = @{+shift};
        $a = 'u' unless defined $a;
        $b = 'u' unless defined $b;
        $a = $a-&gt;pretty if ref $a;
        $b = $b-&gt;pretty if ref $b;
        "[$meth $a $b]";
    }

Now one can finish the script by

    print "side = ", $side-&gt;pretty, "\n";

The method C&lt;pretty&gt; is doing object-to-string conversion, so it
is natural to overload the operator C&lt;""&gt; using this method.  However,
inside such a method it is not necessary to pretty-print the
I&lt;components&gt; $a and $b of an object.  In the above subroutine
C&lt;"[$meth $a $b]"&gt; is a catenation of some strings and components $a
and $b.  If these components use overloading, the catenation operator
will look for an overloaded operator C&lt;.&gt;; if not present, it will
look for an overloaded operator C&lt;""&gt;.  Thus it is enough to use

    use overload nomethod =&gt; \&amp;wrap, '""' =&gt; \&amp;str;
    sub str {
        my ($meth, $a, $b) = @{+shift};
        $a = 'u' unless defined $a;
        $b = 'u' unless defined $b;
        "[$meth $a $b]";
    }

Now one can change the last line of the script to

    print "side = $side\n";

which outputs

    side = [/ [- [sqrt [+ 1 [** [n 1 u] 2]] u] 1] [n 1 u]]

and one can inspect the value in debugger using all the possible
methods.

Something is still amiss: consider the loop variable $cnt of the
script.  It was a number, not an object.  We cannot make this value of
type C&lt;symbolic&gt;, since then the loop will not terminate.

Indeed, to terminate the cycle, the $cnt should become false.
However, the operator C&lt;bool&gt; for checking falsity is overloaded (this
time via overloaded C&lt;""&gt;), and returns a long string, thus any object
of type C&lt;symbolic&gt; is true.  To overcome this, we need a way to
compare an object to 0.  In fact, it is easier to write a numeric
conversion routine.

Here is the text of F&lt;symbolic.pm&gt; with such a routine added (and
slightly modified str()):

    package symbolic;           # Primitive symbolic calculator
    use overload
        nomethod =&gt; \&amp;wrap, '""' =&gt; \&amp;str, '0+' =&gt; \&amp;num;

    sub new { shift; bless ['n', @_] }
    sub wrap {
        my ($obj, $other, $inv, $meth) = @_;
        ($obj, $other) = ($other, $obj) if $inv;
        bless [$meth, $obj, $other];
    }
    sub str {
        my ($meth, $a, $b) = @{+shift};
        $a = 'u' unless defined $a;
        if (defined $b) {
            "[$meth $a $b]";
        } else {
            "[$meth $a]";
        }
    }
    my %subr = (
        n =&gt; sub {$_[0]},
        sqrt =&gt; sub {sqrt $_[0]},
        '-' =&gt; sub {shift() - shift()},
        '+' =&gt; sub {shift() + shift()},
        '/' =&gt; sub {shift() / shift()},
        '*' =&gt; sub {shift() * shift()},
        '**' =&gt; sub {shift() ** shift()},
    );
    sub num {
        my ($meth, $a, $b) = @{+shift};
        my $subr = $subr{$meth}
        or die "Do not know how to ($meth) in symbolic";
        $a = $a-&gt;num if ref $a eq __PACKAGE__;
        $b = $b-&gt;num if ref $b eq __PACKAGE__;
        $subr-&gt;($a,$b);
    }

All the work of numeric conversion is done in %subr and num().  Of
course, %subr is not complete, it contains only operators used in the
example below.  Here is the extra-credit question: why do we need an
explicit recursion in num()?  (Answer is at the end of this section.)

Use this module like this:

    require symbolic;
    my $iter = symbolic-&gt;new(2);        # 16-gon
    my $side = symbolic-&gt;new(1);
    my $cnt = $iter;

    while ($cnt) {
        $cnt = $cnt - 1;                # Mutator '--' not implemented
        $side = (sqrt(1 + $side**2) - 1)/$side;
    }
    printf "%s=%f\n", $side, $side;
    printf "pi=%f\n", $side*(2**($iter+2));

It prints (without so many line breaks)

    [/ [- [sqrt [+ 1 [** [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1]
                            [n 1]] 2]]] 1]
    [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1] [n 1]]]=0.198912
    pi=3.182598

The above module is very primitive.  It does not implement
mutator methods (C&lt;++&gt;, C&lt;-=&gt; and so on), does not do deep copying
(not required without mutators!), and implements only those arithmetic
operations which are used in the example.

To implement most arithmetic operations is easy; one should just use
the tables of operations, and change the code which fills %subr to

    my %subr = ( 'n' =&gt; sub {$_[0]} );
    foreach my $op (split " ", $overload::ops{with_assign}) {
        $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
    }
    my @bins = qw(binary 3way_comparison num_comparison str_comparison);
    foreach my $op (split " ", "@overload::ops{ @bins }") {
        $subr{$op} = eval "sub {shift() $op shift()}";
    }
    foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
        print "defining '$op'\n";
        $subr{$op} = eval "sub {$op shift()}";
    }

Since subroutines implementing assignment operators are not required
to modify their operands (see L&lt;/Overloadable Operations&gt; above),
we do not need anything special to make C&lt;+=&gt; and friends work,
besides adding these operators to %subr and defining a copy
constructor (needed since Perl has no way to know that the
implementation of C&lt;'+='&gt; does not mutate the argument -
see L&lt;/Copy Constructor&gt;).

To implement a copy constructor, add C&lt;&lt; '=' =&gt; \&amp;cpy &gt;&gt; to C&lt;use overload&gt;
line, and code (this code assumes that mutators change things one level
deep only, so recursive copying is not needed):

    sub cpy {
        my $self = shift;
        bless [@$self], ref $self;
    }

To make C&lt;++&gt; and C&lt;--&gt; work, we need to implement actual mutators,
either directly, or in C&lt;nomethod&gt;.  We continue to do things inside
C&lt;nomethod&gt;, thus add

    if ($meth eq '++' or $meth eq '--') {
        @$obj = ($meth, (bless [@$obj]), 1); # Avoid circular reference
        return $obj;
    }

after the first line of wrap().  This is not a most effective
implementation, one may consider

    sub inc { $_[0] = bless ['++', shift, 1]; }

instead.

As a final remark, note that one can fill %subr by

    my %subr = ( 'n' =&gt; sub {$_[0]} );
    foreach my $op (split " ", $overload::ops{with_assign}) {
        $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
    }
    my @bins = qw(binary 3way_comparison num_comparison str_comparison);
    foreach my $op (split " ", "@overload::ops{ @bins }") {
        $subr{$op} = eval "sub {shift() $op shift()}";
    }
    foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
        $subr{$op} = eval "sub {$op shift()}";
    }
    $subr{'++'} = $subr{'+'};
    $subr{'--'} = $subr{'-'};

This finishes implementation of a primitive symbolic calculator in
50 lines of Perl code.  Since the numeric values of subexpressions
are not cached, the calculator is very slow.

Here is the answer for the exercise: In the case of str(), we need no
explicit recursion since the overloaded C&lt;.&gt;-operator will fall back
to an existing overloaded operator C&lt;""&gt;.  Overloaded arithmetic
operators I&lt;do not&gt; fall back to numeric conversion if C&lt;fallback&gt; is
not explicitly requested.  Thus without an explicit recursion num()
would convert C&lt;['+', $a, $b]&gt; to C&lt;$a + $b&gt;, which would just rebuild
the argument of num().

If you wonder why defaults for conversion are different for str() and
num(), note how easy it was to write the symbolic calculator.  This
simplicity is due to an appropriate choice of defaults.  One extra
note: due to the explicit recursion num() is more fragile than sym():
we need to explicitly check for the type of $a and $b.  If components
$a and $b happen to be of some related type, this may lead to problems.

=head2 I&lt;Really&gt; Symbolic Calculator

One may wonder why we call the above calculator symbolic.  The reason
is that the actual calculation of the value of expression is postponed
until the value is I&lt;used&gt;.

To see it in action, add a method

    sub STORE {
        my $obj = shift;
        $#$obj = 1;
        @$obj-&gt;[0,1] = ('=', shift);
    }

to the package C&lt;symbolic&gt;.  After this change one can do

    my $a = symbolic-&gt;new(3);
    my $b = symbolic-&gt;new(4);
    my $c = sqrt($a**2 + $b**2);

and the numeric value of $c becomes 5.  However, after calling

    $a-&gt;STORE(12);  $b-&gt;STORE(5);

the numeric value of $c becomes 13.  There is no doubt now that the module
symbolic provides a I&lt;symbolic&gt; calculator indeed.

To hide the rough edges under the hood, provide a tie()d interface to the
package C&lt;symbolic&gt;.  Add methods

    sub TIESCALAR { my $pack = shift; $pack-&gt;new(@_) }
    sub FETCH { shift }
    sub nop {  }                # Around a bug

(the bug, fixed in Perl 5.14, is described in L&lt;"BUGS"&gt;).  One can use this
new interface as

    tie $a, 'symbolic', 3;
    tie $b, 'symbolic', 4;
    $a-&gt;nop;  $b-&gt;nop;          # Around a bug

    my $c = sqrt($a**2 + $b**2);

Now numeric value of $c is 5.  After C&lt;$a = 12; $b = 5&gt; the numeric value
of $c becomes 13.  To insulate the user of the module add a method

    sub vars { my $p = shift; tie($_, $p), $_-&gt;nop foreach @_; }

Now

    my ($a, $b);
    symbolic-&gt;vars($a, $b);
    my $c = sqrt($a**2 + $b**2);

    $a = 3; $b = 4;
    printf "c5  %s=%f\n", $c, $c;

    $a = 12; $b = 5;
    printf "c13  %s=%f\n", $c, $c;

shows that the numeric value of $c follows changes to the values of $a
and $b.

=head1 AUTHOR

Ilya Zakharevich E&lt;lt&gt;F&lt;ilya@math.mps.ohio-state.edu&gt;E&lt;gt&gt;.

=head1 SEE ALSO

The C&lt;overloading&gt; pragma can be used to enable or disable overloaded
operations within a lexical scope - see L&lt;overloading&gt;.

=head1 DIAGNOSTICS

When Perl is run with the B&lt;-Do&gt; switch or its equivalent, overloading
induces diagnostic messages.

Using the C&lt;m&gt; command of Perl debugger (see L&lt;perldebug&gt;) one can
deduce which operations are overloaded (and which ancestor triggers
this overloading).  Say, if C&lt;eq&gt; is overloaded, then the method C&lt;(eq&gt;
is shown by debugger.  The method C&lt;()&gt; corresponds to the C&lt;fallback&gt;
key (in fact a presence of this method shows that this package has
overloading enabled, and it is what is used by the C&lt;Overloaded&gt;
function of module C&lt;overload&gt;).

The module might issue the following warnings:

=over 4

=item Odd number of arguments for overload::constant

(W) The call to overload::constant contained an odd number of arguments.
The arguments should come in pairs.

=item '%s' is not an overloadable type

(W) You tried to overload a constant type the overload package is unaware of.

=item '%s' is not a code reference

(W) The second (fourth, sixth, ...) argument of overload::constant needs
to be a code reference.  Either an anonymous subroutine, or a reference
to a subroutine.

=item overload arg '%s' is invalid

(W) C&lt;use overload&gt; was passed an argument it did not
recognize.  Did you mistype an operator?

=back

=head1 BUGS AND PITFALLS

=over

=item *

A pitfall when fallback is TRUE and Perl resorts to a built-in
implementation of an operator is that some operators have more
than one semantic, for example C&lt;|&gt;:

    use overload '0+' =&gt; sub { $_[0]-&gt;{n}; },
        fallback =&gt; 1;
    my $x = bless { n =&gt; 4 }, "main";
    my $y = bless { n =&gt; 8 }, "main";
    print $x | $y, "\n";

You might expect this to output "12".
In fact, it prints "&lt;": the ASCII result of treating "|"
as a bitwise string operator - that is, the result of treating
the operands as the strings "4" and "8" rather than numbers.
The fact that numify (C&lt;0+&gt;) is implemented but stringify
(C&lt;""&gt;) isn't makes no difference since the latter is simply
autogenerated from the former.

The only way to change this is to provide your own subroutine
for C&lt;'|'&gt;.

=item *

Magic autogeneration increases the potential for inadvertently
creating self-referential structures.
Currently Perl will not free self-referential
structures until cycles are explicitly broken.
For example,

    use overload '+' =&gt; 'add';
    sub add { bless [ \$_[0], \$_[1] ] };

is asking for trouble, since

    $obj += $y;

will effectively become

    $obj = add($obj, $y, undef);

with the same result as

    $obj = [\$obj, \$foo];

Even if no I&lt;explicit&gt; assignment-variants of operators are present in
the script, they may be generated by the optimizer.
For example,

    "obj = $obj\n"

may be optimized to

    my $tmp = 'obj = ' . $obj;  $tmp .= "\n";

=item *

The symbol table is filled with names looking like line-noise.

=item *

This bug was fixed in Perl 5.18, but may still trip you up if you are using
older versions:

For the purpose of inheritance every overloaded package behaves as if
C&lt;fallback&gt; is present (possibly undefined).  This may create
interesting effects if some package is not overloaded, but inherits
from two overloaded packages.

=item *

Before Perl 5.14, the relation between overloading and tie()ing was broken.
Overloading was triggered or not based on the I&lt;previous&gt; class of the
tie()d variable.

This happened because the presence of overloading was checked
too early, before any tie()d access was attempted.  If the
class of the value FETCH()ed from the tied variable does not
change, a simple workaround for code that is to run on older Perl
versions is to access the value (via C&lt;() = $foo&gt; or some such)
immediately after tie()ing, so that after this call the I&lt;previous&gt; class
coincides with the current one.

=item *

Barewords are not covered by overloaded string constants.

=item *

The range operator C&lt;..&gt; cannot be overloaded.

=back

=cut

# ex: set ts=8 sts=4 sw=4 et:
</pre></body></html>